Hi All,

I am handling NewInspector event to show my custom form when user
clicks on "New Task" or "New Task Request". But somehow I am
getting same message class (i.e. IPM.Task) for both commands.

Can anyone of you pls. suggest a way to determine that whether
NewInspector request is for "Task" or "Task Request"?

Thanks.

There's no way to tell the difference directly. TaskRequestItems cannot be
created by a user, they are created by Outlook when the request is received
in the recipient's Inbox.

Your best bet is to trap the Click event for the respective
CommandBarButtons for the Task entries in the New dropdown. Try this code in
your ThisOutlookSession module to see how to do it:

Option Explicit
Private WithEvents myTaskButton As Office.CommandBarButton
Private WithEvents myTaskRequestButton As Office.CommandBarButton
Private WithEvents objInspectors As Outlook.Inspectors
Enum TaskTypes
RegularTask = 0
TaskRequest = 1
End Enum
Private lngCurrentTaskType As TaskTypes

Private Sub Application_Startup()
Dim objCBs As CommandBars
Dim objCBCs As CommandBarControls

Set objInspectors = Application.Inspectors
Set objCBs = Application.ActiveExplorer.CommandBars
Set myTaskRequestButton = objCBs.FindControl(, 2006) 'TaskRequestItem
Set myTaskButton = objCBs.FindControl(, 1100) 'TaskItem
End Sub

Private Sub myTaskButton_Click(ByVal Ctrl As Office.CommandBarButton,
CancelDefault As Boolean)
'Set global variable to track which button was clicked to be read by the
NewInspector event
lngCurrentTaskType = RegularTask
End Sub

Private Sub myTaskRequestButton_Click(ByVal Ctrl As Office.CommandBarButton,
CancelDefault As Boolean)
'Set global variable to track which button was clicked to be read by the
NewInspector event
lngCurrentTaskType = TaskRequest
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
MsgBox "Task Type = " & lngCurrentTaskType
End Sub


--
Eric Legault (Outlook MVP, MCDBA, MCTS: Messaging & Collaboration)
Try Picture Attachments Wizard for Outlook:
http://www.collaborativeinnovations.ca
Blog: http://blogs.officezealot.com/legault/


"Piyush Gupta" wrote:

Hi All,

I am handling NewInspector event to show my custom form when user
clicks on "New Task" or "New Task Request". But somehow I am
getting same message class (i.e. IPM.Task) for both commands.

Can anyone of you pls. suggest a way to determine that whether
NewInspector request is for "Task" or "Task Request"?

Thanks.